Comments or Suggestions for newbie game?

[petik1]

Hello all, I have finally come around to make my second game. It is a platformer, and it is early (read: very very early) in development. Any comments or suggestions? Thanks! .bin attached.

 

-Michael

[petik1]

Oops.

3811_7_56.bin

[ScumSoft]

END!

 

Got a kick out of that

 

Neat asteroid, I like it.

[petik1]

Here's a newer version. I have a few questions.

 

What's the easiest way of having a new playfield come? For example, I want player0 to reach the end of the screen, which will prompt the new screen.

 

Also, does the AA store make 8K custom carts? This, when finished, definently won't fit 4k.

 

Thanks.

3911_5_24(Lvl.2).bin

[petik1]

Once again, the encouragement and support from the forum is outstanding.

[SeaGtGruff]

Have you posted this in the batari Basic forum yet? I know you haven't included the code for us to look at, but the other batari Basic programmers would probably enjoy trying out the game and offering batari Basic programming examples.

 

What's the easiest way of having a new playfield come? For example, I want player0 to reach the end of the screen, which will prompt the new screen.

 

This is a very basic example, and there are surely better ways to do it, but I want to keep it simple.

 

  rem * example of moving between rooms

  dim room_number = a
  dim movement = b

  room_number = 1 : rem so you can go left or right from the start

  movement = 0 : rem not moving yet

  COLUBK = $00 : rem black

  player0:
  %11000011
  %01100110
  %00111100
  %00011000
  %00011000
  %11111111
  %00011000
  %00011000
end

  player0x = 17
  player0y = 64

main_loop

  COLUP0 = $3A : rem peach

  player0x = player0x + movement : rem move player0

  on room_number gosub room0 room1 room2 : rem draw the room

  drawscreen : rem draw the screen

  if collision(player0,playfield) then player0x = player0x - movement
  rem knock player0 back if collided with playfield

  movement = 0 : rem reset movement before checking joystick
  if joy0left then movement = 255 : rem 255 is equal to -1 (left)
  if joy0right then movement = 1 : rem 1 is equal to +1 (right)

  if player0x = 16 then gosub room_to_the_left
  if player0x = 137 then gosub room_to_the_right

  goto main_loop

room0

  COLUPF = $1C

  playfield:
  ................................
  ................................
  ................................
  ................................
  ................................
  ................................
  X...............................
  X...............................
  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  ................................
  ................................
end

  return

room1

  COLUPF = $4C

  playfield:
  ................................
  ................................
  ................................
  ................................
  ................................
  ................................
  ................................
  ................................
  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  ................................
  ................................
end

  return

room2

  COLUPF = $8C

  playfield:
  ................................
  ................................
  ................................
  ................................
  ................................
  ................................
  ...............................X
  ...............................X
  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  ................................
  ................................
end

  return

room_to_the_left

  room_number = room_number - 1

  player0x = 136

  return

room_to_the_right

  room_number = room_number + 1

  player0x = 17

  return

Basically, you can check the player's x coordinate to see if he's moved to a point where you want the screen to change. You would also want to make him disappear off of one side and reappear on the other side-- i.e., if he moves off the left edge of one screen, he would end up near the right edge of the new screen, or vice versa.

 

Also, does the AA store make 8K custom carts? This, when finished, definently won't fit 4k.

You should PM Albert and ask him. If he can't accommodate you, there are also other places where you can get your games made into cartridges.

 

Michael

 

PS -- In your game, pressing fire continuously causes the man to "levitate." There should be some examples of programming a jumping/falling sprite with "gravity." My little example has no vertical movement or jumping/falling/gravity, just horizontal motion.

 

 

example_of_moving_between_rooms.bas.bin

[GroovyBee]

Once again, the encouragement and support from the forum is outstanding.

 

You could try posting your game in the Homebrew Discussion section on AA to get more coverage. Some people will only download and play the game if it looks interesting to them. With that in mind, adding screenshots and inventing a back story to draw the potential player into the game might help too. The back story should cover who you are playing as and why you are doing the things in the game.